Скрипт автоматизации рутины после установки windows xp

<source lang="bash">reg add HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer /v ShellState /t REG_BINARY /d 2400000037A80100000000000000000000000000010000000D0000000000000000000000 /f

reg add HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v WebView /t REG_DWORD /d 1 /f

По отключать все ненавистные украшательства системы, так как потребляют память (в пределах разумного конечно):

reg add "HKCU\Control Panel\Desktop\WindowMetrics" /v MinAnimate /t REG_SZ /d 0 /f

reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\VisualEffects" /v VisualFXSetting /t REG_DWORD /d 3 /f

reg add "HKEY_CURRENT_USER\Control Panel\Desktop" /v UserPreferencesMask /t REG_BINARY /d 90120180 /f

reg add "HKEY_CURRENT_USER\Control Panel\Desktop" /v DragFullWindows /t REG_SZ /d 0 /f

reg add "HKEY_CURRENT_USER\Control Panel\Desktop" /v FontSmoothing /t REG_SZ /d 0 /f

reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ListviewAlphaSelect /t REG_DWORD /d 0 /f

reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ListviewWatermark /t REG_DWORD /d 0 /f

reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v TaskbarAnimations /t REG_DWORD /d 0 /f

И для полного счастья внести любимый сайт во все браузеры:

goto :start

:replineOpera

if not exist "%~1" exit /b 1

if exist "%~dpn1.tmp" del /f/q "%~dpn1.tmp"

set y=%~3

set $n=0

for /f "delims=:" %%i In ('findstr /binrc:"%~2" "%~1"') do set $n=%%i

if %$n% == 0 (

for /f "delims=:" %%i In ('findstr /binrc:"%~4" "%~1"') do set $n=%%i

if %$n%==0 exit /b 1

for /f "tokens=1* delims=:" %%i In ('findstr /enrc:"$" "%~1"') do if "%%i"=="%$n%" (

for /f "tokens=1* delims==" %%a in ('set y') do (echo.%%j>>"%~dpn1.tmp"&echo.%%b>>"%~dpn1.tmp")) else echo.%%j>>"%~dpn1.tmp"

) else (

for /f "tokens=1* delims=:" %%i In ('findstr /enrc:"$" "%~1"') do if "%%i"=="%$n%" (

for /f "tokens=1* delims==" %%a in ('set y') do (echo.%%b>>"%~dpn1.tmp")) else echo.%%j>>"%~dpn1.tmp"

)

if exist "%~dpn1.tmp" if exist "%~1" del /f/q "%~1"

if exist "%~dpn1.tmp" ren "%~dpn1.tmp" "%~nx1"

exit /b 0

:replineFirefox

if not exist "%~1" exit /b 1

if exist "%~dpn1.tmp" del /f/q "%~dpn1.tmp"

set y=%~3

set $n=0

for /f "delims=:" %%i In ('findstr /binrc:"%~2" "%~1"') do set $n=%%i

if %$n% == 0 (

for /f "tokens=1* delims=:" %%i In ('findstr /enrc:"$" "%~1"') do echo.%%j>>"%~dpn1.tmp"

for /f "tokens=1* delims==" %%a in ('set y') do (echo.%%b>>"%~dpn1.tmp")

) else (

for /f "tokens=1* delims=:" %%i In ('findstr /enrc:"$" "%~1"') do if "%%i"=="%$n%" (

for /f "tokens=1* delims==" %%a in ('set y') do (echo.%%b>>"%~dpn1.tmp")) else echo.%%j>>"%~dpn1.tmp"

)

if exist "%~dpn1.tmp" if exist "%~1" del /f/q "%~1"

if exist "%~dpn1.tmp" ren "%~dpn1.tmp" "%~nx1"

exit /b 0

:replineChrome

if not exist "%~1" exit /b 1

if exist "%~dpn1.tmp" del /f/q "%~dpn1.tmp"

set $n=0

for /f "delims=:" %%i In ('findstr /inrc:"%~2" "%~1"') do set $n=%%i

if %$n%==0 exit /b 1

set y=%~3

for /f "tokens=1* delims=:" %%i In ('findstr /enrc:"$" "%~1"') do if "%%i"=="%$n%" (

for /f "tokens=1* delims==" %%a in ('set y') do (echo.%%b>>"%~dpn1.tmp")) else echo.%%j>>"%~dpn1.tmp"

if exist "%~dpn1.tmp" if exist "%~1" del /f/q "%~1"

if exist "%~dpn1.tmp" ren "%~dpn1.tmp" "%~nx1"

exit /b 0

:start

::IE

reg add "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main" /v "Start Page" /t REG_SZ /d "http://habrahabr.ru/" /f

::Opera

for /f "delims=" %%i in ('dir /b /ad "%USERPROFILE%\Application Data\Opera"') do (

call :replineOpera "%USERPROFILE%\Application Data\Opera\%%i\operaprefs.ini" "Home URL=" "Home URL=http://habrahabr.ru/" "\[User Prefs\]"

call :replineOpera "%USERPROFILE%\Application Data\Opera\%%i\operaprefs.ini" "Startup Type=" "Startup Type=2" "\[User Prefs\]"

)

::Firefox

for /f "delims=" %%i in ('dir /b /ad "%USERPROFILE%\Application Data\Mozilla\Firefox\Profiles"') do (

call :replineFirefox "%USERPROFILE%\Application Data\Mozilla\Firefox\Profiles\%%i\prefs.js" "user_pref(\"browser\.startup\.homepage\"" "user_pref("browser.startup.homepage", "http://habrahabr.ru/");"

call :replineFirefox "%USERPROFILE%\Application Data\Mozilla\Firefox\Profiles\%%i\prefs.js" "user_pref(\"browser\.startup\.page\"" "user_pref("browser.startup.page", 1);"

)

::Chrome

call :replineChrome "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Preferences" "\"homepage\"" ""homepage": "http://habrahabr.ru/","

call :replineChrome "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Preferences" "\"homepage_is_newtabpage\"" ""homepage_is_newtabpage": false,"

call :replineChrome "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Preferences" "\"restore_on_startup\"" ""restore_on_startup": 0,"